REM Shows how to find server applications that meet the specified filters, using the global discovery client.
REM
REM Find all latest examples here: https://opclabs.doc-that.com/files/onlinedocs/OPCLabs-OpcStudio/Latest/examples.html .
REM OPC client and subscriber examples in Visual Basic on GitHub: https://github.com/OPCLabs/Examples-QuickOPC-VB .
REM Missing some example? Ask us for it on our Online Forums, https://www.opclabs.com/forum/index ! You do not have to own
REM a commercial license in order to use Online Forums, and we reply to every post.

Private Sub EasyUAGlobalDiscoveryClient_QueryServers_Main_Command_Click()
    OutputText = ""
    
    ' Define which GDS we will work with.
    Dim gdsEndpointDescriptor As New UAEndpointDescriptor
    gdsEndpointDescriptor.UrlString = "opc.tcp://opcua.demo-this.com:58810/GlobalDiscoveryServer"
    
    ' Instantiate the global discovery client object
    Dim globalDiscoveryClient As New EasyUAGlobalDiscoveryClient
    
    ' Find all servers registered in the GDS.
    Dim startingRecordId As Integer: startingRecordId = 0
    Dim maximumRecordsToReturn As Integer: maximumRecordsToReturn = 0
    Dim applicationName As String: applicationName = ""
    Dim applicationUriString As String: applicationUriString = ""
    Dim productUriString As String: productUriString = ""
    Dim serverCapabilities: serverCapabilities = Array()
    Dim lastCounterResetTime As Date
    Dim serverOnNetworkArray As Variant
    On Error Resume Next
    Dim applicationId As UANodeId
    Call globalDiscoveryClient.QueryServers( _
      gdsEndpointDescriptor, _
      startingRecordId, _
      maximumRecordsToReturn, _
      applicationName, _
      applicationUriString, _
      productUriString, _
      serverCapabilities, _
      lastCounterResetTime, _
      serverOnNetworkArray)
    If Err.Number <> 0 Then
        OutputText = OutputText & "*** Failure: " & Err.Source & ": " & Err.Description & vbCrLf
        Exit Sub
    End If
    On Error GoTo 0
    
    ' Display results
    Dim i: For i = LBound(serverOnNetworkArray) To UBound(serverOnNetworkArray)
        Dim serverOnNetwork As UAServerOnNetwork
        Set serverOnNetwork = serverOnNetworkArray(i)
        OutputText = OutputText & vbCrLf
        OutputText = OutputText & "ServerName name: " & serverOnNetwork.ServerName & vbCrLf
        OutputText = OutputText & "Discovery URL string: " & serverOnNetwork.DiscoveryUrlString & vbCrLf
        OutputText = OutputText & "Server capabilities: " & serverOnNetwork.serverCapabilities.ToString & vbCrLf
    Next
End Sub